The following document provides a step by step guide to creating your very own custom
Wabbajack Staff. This should be useful to anyone wanting to recreate my mod v1.6

-------------

Must download and install OBSE + OBME

Oblivion Script Extender (OBSE)
http://obse.silverlock.org/
v0020

Oblivion Magic Extender (OBME) - Available from TESNEXUS, By JRoush
http://www.tesnexus.com/downloads/file.php?id=31981

Open the Oblivion construction set using the OBSE editor

File -> Data -> Double left click Oblivion.esm (should see X to confirm it selected)
Press OK (Wait for construction set to finish loading master file)

-------------

Gameplay -> Edit Scripts... (OR press the 'Scripts' button - Pencil Image)

Script -> New
Script Type -> Quest

scn zWabbajackQuestScript

ref trueform
ref target

begin gamemode

end

Script -> Save (OR press the 'Save' button - Disk Image)

-------------

Character -> Quests... (OR press the 'Q' button)

Right click on the Editor ID list -> New -> New Form Editor ID - zWabbaCheck
-Script -> zWabbajackQuestScript

Make sure Start Game Enabled is ticked
Press OK

-------------

Character -> Faction...

Right click on the Editor ID list -> New -> New Form Editor ID - zWabbajackFaction

Name: Wabbajack Faction

Interfaction Relations

Right click -> New -> CreatureFaction
set mod value to -50

Right click -> New -> Prey
set mod value to 100

Press OK

-------------

Object Window -> Actors -> Creature

Double left click WabbajackSheep - change editor ID to zWabbajackSheep
Script: NONE (We will create and select the new script later)

Factions (tab)
Right click 'Prey' and Delete

With the Faction window open - select the zWabbajackFaction from the Editor ID list
Left click and drag this faction into the creature Faction tab

You should see Rank:0 Faction: zWabbajackFaction

Press OK - Select Yes to create new form

-------------

Object Window -> Actors -> LeveledCreature

Double left click WabbajackList - change editor ID to zWabbajackList

Creature Template -> zWabbajackSheep

The default WabbajackList contains 8 creatures
Right click and delete each of these (We will rebuild the list)

Right click -> New
Press the object dropdown menu button, now press the 'c' key on your keyboard
This will jump to the first object with 'c' in the name, press 'r' next
This will bring you to the very first creature we will add to the list

CreatureAtronachFlame (First Mob on Oblivion creature list)
...
CreatureZombieHeadless4 (Last Mob on Oblivion creature list)

Now repeat the above step for all the creatures you want added to the list

To add creatures from Shivering Isles press s , e , c , r

SECreatureAtronachFlesh1 (First Mob on SE creature list)
...
SECreatureSkinnedHoundGreater (Last Mob on SE creature list)

When you are finished adding creatures to the list press OK

(Make sure only creatures are added to this list)

-------------

Gameplay -> Edit Scripts... (OR press the 'Scripts' button - Pencil Image)

Script -> New
Script Type -> Magic Effect

scn zWabbajackSpellEffect

ref self

begin ScriptEffectStart
set self to GetSelf

if ( self.IsRidingHorse == 0 ) && ( self.GetDead == 0 ) && ( self != player ) && ( IsActor || IsCreature )

;message "Wabbajack start"

set zWabbaCheck.target to GetSelf

if ( GetInFaction zWabbajackFaction )
return
endif

if ( self.isRefEssential == 1 )
self.setRefEssential 0
endif

; create replacement creature
placeAtMe zWabbajackList 1

endif

end

Script -> Save (OR press the 'Save' button - Disk Image)

-------------

Gameplay -> Magic Effects...

New -> New MGEF EditorID - 6969 (or enter your own unique ID...)

General Properties
-Name Wabbajack
-Tick Dynamic mgef code
-school Alteration
-Hostility Neutral

Magic Items
-Tick use in Enchantments

Mag/Dur/Range/Area
-Tick Has OnTarget Range

Effect Handler
-Scripted
-Script -> zWabbajackSpellEffect
-Tick Allow 'Script Always Applies'
-Tick UserParam is FormID
-Tick UserParam is MgefCode

Press Apply - Press Done

-------------

Gameplay -> Edit Scripts... (OR press the 'Scripts' button - Pencil Image)

Script -> New
Script Type -> Object

scn zWabbajackCreatureScript

short doOnce
float timer
short done

ref trueformRef
ref me

begin OnDeath

trueformRef.kill
trueformRef.enable
trueformRef.moveto me
me.disable
me.PositionCell 0 0 0 0 Aleswell
me.DeleteReference

end

begin OnMagicEffectHit 6969

set zWabbaCheck.trueform to trueformRef
placeAtMe zWabbajackList 1
me.disable
me.PositionCell 0 0 0 0 Aleswell
me.DeleteReference

end

begin OnLoad
if doOnce == 0 && GetSelf != 0
set me to GetSelf

if ( zWabbaCheck.trueform == 0 )
set trueformRef to zWabbaCheck.target
else
set trueformRef to zWabbaCheck.trueform
set zWabbaCheck.trueform to 0
endif

trueformRef.disable
trueformRef.PositionCell 0 0 0 0 Aleswell
pme STRP
playsound SPLConjurationCast
set doOnce to 1
endif
end

begin gamemode
if done == 0
set timer to timer + getsecondspassed
if timer > 10

if me.GetDead == 0
; message "Wabbajack quest script: replacement still alive, disabling and moving target back"
trueformRef.enable
trueformRef.moveto me
me.disable
me.PositionCell 0 0 0 0 Aleswell
me.DeleteReference
endif

set done to 1
endif
endif
end

Script -> Save (OR press the 'Save' button - Disk Image)

-------------

Object Window -> Actors -> Creature

Double left click zWabbajackSheep
Script: zWabbajackCreatureScript

Press OK

-------------

Object Window -> Magic -> Enchantment

Right click - New

ID - zWabbajack
Type - Staff

Deselect (untick) Auto-Calculate [charge amount and enchantment cost both 0]

Right click Effects - New

Magic Effect - 6969 'Wabbajack'
Range - Target

General Property Overrides
Name - Wabbajack
School - Alteration
Hostility - Neutral

VFX Overrides
-DGAT 'Damage Attribute'

Press OK (The new effect 'Wabbajack' should now be visible in the Effects list)
Press OK (This closes the Enchantment window which poped up - should see new enchant added)

-------------

Object Window -> Items -> Weapon - Weapons -> StaffSheogorath

Double left click SE12StaffofSheogorath - change editor ID to zStaffofSheogorath
-Enchanting: zWabbajack
-Enchantment: 0
-Weight: 0
-Value: 0
-Tick Ignores Normal Weapon Resistance

Press OK - Select Yes to create new form

-------------

Gameplay -> Edit Scripts... (OR press the 'Scripts' button - Pencil Image)

Script -> New
Script Type -> Quest

scn zAddWabbajackStaff

Ref Item
Short doonce

begin GameMode

if doonce == 0
set Item to zStaffofSheogorath
player.additem Item 1
set doonce to 1
endif

end

Script -> Save (OR press the 'Save' button - Disk Image)

-------------

Character -> Quests... (OR press the 'Q' button)

Right click on the Editor ID list -> New -> New Form Editor ID - zWabbaAdd
-Script -> zAddWabbajackStaff

Make sure Start Game Enabled is ticked
Press OK

-------------

File -> Save -> File name: Multi Wabbajack
Press 'Save'

File -> Data...
left click the new mod 'Multi Wabbajack.esp'

Created By: KMSvalley

Summary:---Multiple Wabbajack Targets

---After 10secs returns Trueform

---OnDeath returns Trueform

Requires OBSE and OBME

(DONT PRESS OK - JUST CLOSE THIS WINDOW THE DESCRIPTION ADDED WILL BE SAVED WITH THE MOD)

Launch Oblivion -> Data Files -> Double left click 'Multi Wabbajack.esp' (X will confirm)
Press OK -> Play -> New Game or Load Game -> Wait a few seconds for staff to be added to player

Equip the Staff - Wabbajack!

Wabbajack, Wabbajack, Wabbajack
Wabbajack, Wabbajack, Wabbajack