About this mod
Massively increase boost duration to provide X4 travel drive-like behavior in XR
- Permissions and credits
I generated this mod with XSLT, using the following (xr_traveldrivemod.xslt):
<!-- Run Example:
transform -xsl:"C:/xr_traveldrivemod.xslt" -it:main inF="D:/Games/Steam/steamapps/common/X Rebirth/" outF="D:/Out/" root="XR_extracted/" universe="xu_ep1_universe" clusters="clusters"
-->
<xsl:stylesheet version="3.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="utf-8" indent="yes" />
<xsl:strip-space elements="*" />
<xsl:param name="inF" select="inF"/>
<xsl:param name="outF" select="outF"/>
<xsl:param name="root" select="root"/>
<xsl:param name="clusters" select="clusters"/>
<xsl:param name="universe" select="universe"/>
<xsl:variable name="modID" select="'infiniteboost'"/>
<xsl:variable name="sourceString" select="concat($inF,$root)"/>
<xsl:variable name="outputString" select="concat($outF,$modID)"/>
<xsl:variable name="sourceURI" select="concat('file:///',encode-for-uri(replace($sourceString,'\\','/')))"/>
<xsl:variable name="outputURI" select="concat('file:///',encode-for-uri(replace($outputString,'\\','/')))"/>
<xsl:template name="main">
<xsl:result-document href="{concat($outputURI,'/content.xml')}">
<content id="{$modID}"
name="Infinite Boost" description="Massively increase boost duration to provide X4 travel drive-like behavior in XR" author="{concat('metame','''','s Generator')}"
date="{format-date(current-date(),'[Y0001]-[M01]-[D01]')}"
version="1" save="0">
</content>
</xsl:result-document>
<!-- This will call the macros template -->
<xsl:for-each select="collection(concat($sourceURI,'assets/props/SurfaceElements/Macros','?recurse=no;select=','shieldgenerator_player_*_macro','.xml'))">
<xsl:result-document href="{replace(document-uri(.),replace($sourceString,' ','%20'),concat($outputString,'/'))}">
<xsl:apply-templates />
</xsl:result-document>
</xsl:for-each>
</xsl:template>
<!-- How to process each macro file -->
<xsl:template match="macros">
<diff>
<replace sel="/macros/macro/properties/boost/@duration"><xsl:value-of select="1000000*macro/properties/boost/@duration"/></replace>
</diff>
</xsl:template>
</xsl:stylesheet>