Scriptname Paucey_SC3 extends ActiveMagicEffect
;Tooltip helper for the Creation Kit
{If to add a Synth Component when NPC dies}

;Declare a property to hold the Synth Component item
MiscObject property synthDeathItem Auto
;Tooltip helper for the Creation Kit
{What will potentially appear on the NPC when they die}
;Declare a property for the Chance Global Variable
GlobalVariable Property gv_Chance Auto
;Tooltip helper for the Creation Kit
{Variable that holds the chance out of 100 that an NPC will be a Synth (default 1)}
;Declare a property for the CanUnique Global Variable
GlobalVariable Property gv_CanUnique Auto
;Tooltip helper for the Creation Kit
{Variable that holds whether Unique NPCs can be Synths (default 0)}
;Declare a property for the ModToggle Global Variable
GlobalVariable Property gv_ModToggle Auto
;Tooltip helper for the Creation Kit
{Variable that holds whether the Mod's scripts run or not (default 1)}

;Declare local variable to hold the NPC information
actor poorDeadFella
;Declare local variable to hold the Chance Global Variable
float chance
;Declare local variable to hold the CanUnique Global Variable
int canUnique
;Declare local variable for the Maximum Number for the randomizaer
float maxNumber
;Declare local variable to hold the ModToggle Global Variable
int modToggle
;Declare local variable for the randomizer
int random

;A function for cleaning-up the local variables once they're no longer needed
function CleanUp()
chance = 0
canUnique = 0
maxNumber = 0
modToggle = 0
random = 0
poorDeadFella = None
endFunction

;A function to generate the Synth Component so that the main Event functions are easier to read
function AddSynthComp()
;Place the Synth Component on the corpse of the NPC
poorDeadFella.AddItem(synthDeathItem, 1, true)
endFunction

;A function to retrieve the Global Variable properties
function GetModSettings()
;Check if the properties contain anything before trying to retrieve them
if gv_ModToggle && gv_Chance && gv_CanUnique
;Assigns the ModToggle Global Variable to the ModToggle local variable
modToggle = gv_ModToggle.GetValue() as Int
;Assigns the Chance Global Variable to the Chance local variable
chance = gv_Chance.GetValue()
;Assigns the CanUnique Global Variable to the CanUnique local variable
canUnique = gv_CanUnique.GetValue() as Int
;Determines the maximum number that will be given to the randomizer based on the Chance variable
maxNumber = (100/Chance)
endif
endFunction

;An event that triggers when the Magic Effect activates - used to capture the NPC's value
Event OnEffectStart(Actor akTarget, Actor akCaster)
;Checks if the Actor contains information before assigning the poorDeadFella variable
if akTarget
;Assigns the NPC's information to the PoorDeadFella variable to be used upon their death
poorDeadFella = akTarget
else
;Runs the clean-up function
Cleanup()
endif
endEvent

;An event that triggers when the NPC dies
Event OnDying(Actor akKiller)
;Retrieves the current settings of the mod
GetModSettings()
;Checks if the NPC is still, in fact, in the game and that the modToggle boolean is enabled
if poorDeadFella && modToggle
;A random number between 1 and the MaxNumber value, stored as an integer
random = Utility.RandomInt(1, maxNumber as Int)
;If the random number generated matches 1, and Unique NPCs can be synths
if random == 1 && canUnique
;Adds the Synth Component to the NPC's corpse
AddSynthComp()
;Runs the clean-up function
Cleanup()
;If the random number generated matches 1, and the NPC wasn't Unique
elseif random == 1 && !(poorDeadFella.GetActorBase().IsUnique())
;Adds the Synth Component to the NPC's corpse
AddSynthComp()
;Runs the clean-up function
Cleanup()
endif
;Runs the clean-up function
Cleanup()
endif
;Runs the clean-up function
CleanUp()
endEvent

Scriptname Paucey_SC4 extends ReferenceAlias

;Property that holds the PipBoy item
Armor property PipBoy auto
;Property that holds the Holotape item
Holotape property SettingsHolotape auto
;Property that holds the player reference
Actor PlayerREF

;Event that runs on initialization. Adds a Holotape to the Player's inventory if they have a Pipboy - for example, if one were to install the Holotape mod and load a saved game where they already have a Pipboy.
Event OnInit()
;Gets the player reference once (so that the function doesn't have to be called over and over again)
PlayerREF = GetActorReference()
;The Event that triggers when a menu opens (found at the end of the script) requires a registration declaration. It's included here as this is the OnInit() and is guaranteed to run.
RegisterForMenuOpenCloseEvent("PipboyMenu")
;If the Player has a PipBoy
if PlayerREF.GetItemCount(PipBoy)
;Add a copy of the Holotape to the player's inventory
PlayerREF.AddItem(SettingsHolotape, abSilent=False)
;Clears the PlayerRef variable
PlayerREF = None
;Ends the Quest and prevents the script from running in the future
GetOwningQuest().Stop()
endIf
endEvent

;Event that runs when the player moves to a new Location - this is here for the rare instance of a player starting a new game and not going through the Vault 111 sequence of acquiring a Pipboy. This Event assumes someone starts the game, gets a Pipboy some other way, and then moves to a new location.
Event OnLocationChange(Location akOldLoc, Location akNewLoc)
;If the Player has a PipBoy
if PlayerREF.GetItemCount(PipBoy)
;Adds a copy of the Holotape to the player's inventory
PlayerREF.AddItem(SettingsHolotape, abSilent=False)
;Clears the PlayerRef variable
PlayerREF = None
;Ends the Quest and prevents the script from running in the future
GetOwningQuest().Stop()
endIf
endEvent

;Event that triggers when the Player accesses the PipBoy menu. This event adds a copy of the Holotape when the player receives their Pipboy for the first time during the Vault 111 sequence. Or, if the OnInit and OnLocationChange don't meet the criteria for adding a Holotape (for whatever reason), this will add a Holotape to the player's inventory when they open their PipBoy.
Event OnMenuOpenCloseEvent(string asMenuName, bool abOpening)
;If the menu was the PipBoy Menu and the menu was Opening
if (asMenuName == "PipboyMenu") && (abOpening)
;Adds a copy of the Holotape to the Player's inventory - but does so silently so as to not interrupt the Tutorial messages played when the Pipboy is used for the first time
PlayerREF.AddItem(SettingsHolotape, abSilent=True)
;Clears the PlayerRef variable
PlayerREF = None
;Ends the Quest and prevents the script from running in the future
GetOwningQuest().Stop()
endif
endEvent